跑完monkey自动关机

echo off
::此批处理的功能：
::1.获取当前APK的packageName、versionCode、versionName
::2.安装与卸载APK包
::3.运行monkey，同时把logcat的日志、logcat的错误日志、monkey日志存到到文件夹中，执行完monkey之后，进行关机

::---------注意：需要修改的值，begin
::monkey跑的次数
set monkeyCount=100000
::包名
set apkname=CLauncher_2.9.0.9_RELEASE
::---------需要修改的值,end

echo monkey执行次数为：%monkeyCount%

echo 获取当前时间
set /a t1=(1%time:~0,2%-100)*1
if %t1% LSS 10 set t1=0%t1%
set ymd_hms=%date:~0,4%%date:~5,2%%date:~8,2%%t1%%time:~3,2%%time:~6,2%
echo 日志存放路径为：%ymd_hms%
md %ymd_hms%

echo 当前apk相关信息（packageName、versionCode、versionName）
call aapt dump badging %apkname%.apk |findstr /n /i /C:"package: name=" >>%ymd_hms%\apkInfo.txt
for /f tokens^=2^ delims^=^' %%i in (%ymd_hms%\apkInfo.txt) do set packageName=%%i
for /f tokens^=4^ delims^=^' %%i in (%ymd_hms%\apkInfo.txt) do set versionCode=%%i
for /f tokens^=6^ delims^=^' %%i in (%ymd_hms%\apkInfo.txt) do set versionName=%%i
echo 当前APK为：%apkname%>>%ymd_hms%\apkInfo.txt
echo 包名为：%packageName% >>%ymd_hms%\apkInfo.txt
echo versionCode为：%versionCode% >>%ymd_hms%\apkInfo.txt
echo versionName为：%versionName% >>%ymd_hms%\apkInfo.txt

echo 安装与卸载APK
call adb uninstall %packageName%
call adb install %apkname%.apk

echo 判断当前APK是否混淆
call apktool d %apkname%.apk
set path=%cd%
cd /d %apkname%\smali\com\cyou\cma\clauncher\a\
if %errorlevel% == 0 set ss=是否混淆：混淆
if %errorlevel% == 1 set ss=是否混淆：未混淆
cd /d %path%
echo %ss% >>%ymd_hms%\apkInfo.txt
echo %cd%
::rd /s /q %apkname%

echo 打印logcat日志
call start /b adb logcat -v time >%ymd_hms%\logcat.txt
call start /b adb logcat -v time *:E>%ymd_hms%\Error_logcat.txt

echo 执行monkey
call adb shell monkey -p %packageName% --pct-touch 70 --pct-motion 20 --pct-trackball 10 --pct-syskeys 0 --throttle 300 -v-v-v %monkeyCount%>%ymd_hms%\monkey.txt

::如果未监控到手机，则不会关机，否则关机
echo monkey执行完毕关机
for /f "tokens=1*delims=:" %%i in ('adb devices ^|findstr device ') do echo %%j&set /a n+=1
echo 行数为：%n%
if %n% GTR 1 (shutdown -s ) else (echo 请把手机连接电脑，并重试)
pause

版权声明：本文为博主原创文章，未经博主允许不得转载。